问用IA32汇编语言处理函数的几个问题
EN

Stack Overflow用户

提问于 2014-11-11 21:13:11

回答 1查看 323关注 0票数 1

我正在用汇编语言编写计算降雪的代码。它要求用户提供在执行循环中下雪的数量(以英寸为单位)，直到用户输入0才能打破循环。同样在循环中，金额是彼此相加的。一旦输入0，程序就应该打印总降雪量(以英尺和英寸为单位)。

我的程序有三个函数给我: printStr、readUInt和printUInt以及我的主程序。我理解printStr和readUInt是如何工作的，但我不明白printUInt是如何工作的，所以我希望有人能向我解释这一点。

另外，当我不得不打印“总降雪量：#英尺和#英寸”时，我很难弄清楚如何在字符串中打印这两个数字，关于这一点的一些建议也是有帮助的。

我已经为此做了几个小时了，如果我不是完全困惑的话，我就不会在这里了。

printStr (edi =要打印以空结尾的字符串的地址)

    printStr:
  pushq %rbp
  movq %rsp,%rbp
  subq $24,%rsp
  movl %ebx, -4(%rbp)

  movl %edi, %ecx   # Copy the "Start"

printStr_loop: 
  movb (%ecx),%al
  cmpb $0,%al
  jz   printStr_end 

  # Syscall to print a character
  movl $4, %eax     # Print (write) syscall
  movl $1, %ebx     # Screen (file)
#  movl $Hello, %ecx
  movl $1, %edx     # One character
  int $0x80

  addl $1, %ecx    
  jmp printStr_loop

printStr_end:
  movl $-1,%eax
  movl $-1,%ecx
  movl $-1,%edx
  movl -4(%rbp), %ebx
  leave
  ret

.data
printUIntBuffer: .asciz "          "
printUIntBufferEnd=.-2

.text

printUInt (edi =要打印的无符号整数)：

    printUInt:
  pushq %rbp
  movq %rsp,%rbp
  subq $24,%rsp
  movl %ebx, -4(%rbp)
  movl %edi, -8(%rbp)
  movl $10, -12(%rbp)  # Constant 10 used for division/modulus  


  movl %edi, %eax   # eax = digits left to convert
  movl $printUIntBufferEnd,%ecx  # %ecx is the insert point
  # Convert each digit into a characters  
printUInt_loop:
     movl $0, %edx  # Reset high portion for division
     divl -12(%rbp)  # Divide edx:eax by 10; edx=Remainder / eax = quotient
     addb $'0',%dl
     movb %dl,0(%ecx)
     subl $1,%ecx
     testl %eax,%eax
     jnz   printUInt_loop 
# Done with loop, print the buffer
   movl %ecx,%edi
   addl $1,%edi
   call printStr

printUInt_end:
  movl $-1,%eax
  movl $-1,%ecx
  movl $-1,%edx
  movl -8(%rbp), %edi
  movl -4(%rbp), %ebx
  leave
  ret

.data
readUInt_bufferStart = .
readUInt_buffer: .ascii " "

.text

readUInt (返回%eax中读取的无符号int )

readUInt:
  pushq   %rbp         # Save the old rpb
  movq    %rsp, %rbp   # Setup this frames start

  movl %ebx,-4(%rbp)


  movl $0,%eax   # initialize accumulator

readUInt_next_char:
  # Read a character
  movl %eax,-8(%rbp)
  movl $3, %eax   # issue a read
  movl $1,%ebx   # File descriptor 1 (stdin)
  movl $1,%edx   # sizet = 1 character
  movl $readUInt_bufferStart,%ecx
  int  $0x80    # Syscall
  movl -8(%rbp),%eax

  # Get the character
  movb readUInt_bufferStart,%bl
  cmpb   $'0',%bl
  jb     readUInt_end
  cmpb   $'9',%bl
  ja     readUInt_end

  movl   $10,%edx
  mul    %edx
  subb   $'0',%bl
  addl   %ebx,%eax
  jmp    readUInt_next_char

readUInt_end:
  movl $-1,%ecx
  movl $-1,%edx
  movl -4(%rbp),%ebx
  leave
  ret

主要数据：

    .data


AskSF: .asciz "How many inches of snow to add (0 when done): "
TotalSF: .asciz "Total snowfall: %d feet and inches "


.text

主要：

    do_while:
movl $AskSF, %edi 
call printStr #asking for amount of snowfall
call readUInt
addl %eax,%edx  #adding amounts of snowfall together
movl %eax,%ecx  #moving entered amount to compare with 0
cmpl $0,%ecx    # checking if amount is 0 to see if loop should exit
jne do_while

#below here I was just experimenting looking for solutions

movl $TotalSF,%edi
call printStr
movl %edx,%edi
call printUInt

gcc

assembly

att

x86

腾讯特效SDK 2.5折起

美颜基础/原子能力套餐低至1500元/月，提供丰富的美化能力，支持全平台集成

回答 1

Stack Overflow用户

回答已采纳

发布于 2014-11-12 00:55:23

printUInt例程的工作方式如下：

取整数(最初在%edi中，但在%eax中)
重复将其除以10，并找到余数(除数后在%edx中找到)。这个余数是被除数的最后一个数字，或者是最右边的数字.
将"0“的ASCII代码添加到这个最右边的数字中，以获得该数字的ASCII代码。
将结果值存储在%ecx所指向的内存中，并减少%ecx (字符串从右到左放置在内存中)。
重复直到商数(%eax)为零为止，这意味着所有的数字都打印出来了。
调用打印例程，指向内存中字符串中的第一个数字。

例如：

从%edx:%eax = 0:113开始
除以10：%eax = 11，%edx =3
加48至3: 51 (或ASCII "3")
将51存储在字符串所在的内存位置(现在是“3")。
除以10：%eax = 1，%edx =1
加48至1: 49 (ASCII "1")
字符串存储49 (现为“13")
除以10：%eax = 0，%edx =1
加48至1: 49 (ASCII "1")
字符串存储49 (现为“113")
停止，因为%eax =0
打印字符串。

为了以英尺和英寸来打印你的答案，我建议将任务分解成4个打印指令，获得了英尺和英寸的组件，并将它们放在堆栈上：

使用printStr例程打印“总降雪量：”
打印脚(从堆栈中检索脚值并在调用printUInt之前放入%edi )
使用printStr例程打印“和”
打印英寸(从堆栈中检索英寸值并放入%edi.)

像这样的东西应该能起作用(但可能更干净)：

.data

TotalSF1: .asciz "Total snowfall: "
TotalSF2: .asciz " feet and "
TotalSF3: .asciz " inches\n"

.text

do_while:
    movl $AskSF, %edi
    call printStr
    call readUInt
    addl %eax, %ebx # %ebx doesn't get clobbered 
                    # by function calls, so use it for sum
    movl %eax, %ecx
    cmpl $0, %ecx
    jne do_while

movl $TotalSF1, %edi # print the first bit of the answer
call printStr
xor %edx, %edx       # zero out %edx in prep for division
movl $12, %ecx       # number of inches in a foot (imperialist!)
movl %ebx,%eax       # put total snowfall in %eax
divl %ecx            # divide %edx:%eax by 12 to get ft + in
push %edx            # put inches on the stack to keep it safe
movl %eax, %edi      # print out feet
call printUInt
movl $TotalSF2, %edi # print out the middle bit of the answer
call printStr
pop %edi             # print out inches
call printUInt
movl $TotalSF3, %edi # print closing bit of answer
call printStr

movl $1, %eax        # exit nicely
movl $0, %ebx
int $0x80