【汇编】（八）更灵活的定位内存地址的方法

前言

前面，我们用 [0]、[bx] 的方法，在访问内存的指令中，定位内存单元的地址。在这一篇博文中，我们主要讲解一些更灵活的定位内存地址的方法和相关的编程方法。  

and 和 or 指令

and 指令：逻辑与指令，按位进行与运算

例如指令：

mov al, 01100011B 
and al, 00111011B

执行后：al = 00100011B；

通过该指令可将操作对象的相应位设为0，其他位不变。

例如：

• 将 al 的第6位设为0：and al, 10111111B；
• 将 al 的第7位设为0：and al, 01111111B；
• 将 al 的第0位设为0：and al, 11111110B；  

or 指令：逻辑或指令，按位进行或运算

例如指令：

mov al, 01100011B 
or al, 00111011B

执行后：al = 01111011B；

通过该指令可将操作对象的相应位设为1，其他位不变。

例如：

• 将 al 的第6位设为1：and al, 01000000B；
• 将 al 的第7位设为1：and al, 10000000B；
• 将 al 的第0位设为1：and al, 00000001B；  

关于 ASCII 码

世界上有很多编码方案，有种方案叫做 ASCII 编码，是在计算机系统中通常被采用的。

简单地说，所谓编码方案，就是一套规则，它约定了用什么样的信息来表示现实对象。

比如说，在 ASCII 编码方案中，用 61H 表示 “a”，62H 表示 “b”。

一种规则需要人们遵守才有意义。

一个文本编辑过程中，就包含着按照 ASCII 编码规则进行的编码和解码。

在文本编辑过程中，我们按一下键盘的 a 键，就会在屏幕上看到 “a”，但这是怎样一个过程呢？

就是给显卡提供 “a” 的 ASCII 码，61H，也就是写入显存中；  

以字符形式给出的数据

我们可以在汇编程序中，用 '…' 的方式指明数据是以字符的形式给出的，编译器将把它们转化为相对应的 ASCII 码，如下：

assume ds:data
data segment
 db 'unIX' 
 db 'foRK'
data ends
code segment
  start:mov al,'a'
        mov bl,'b'
        mov ax,4c00h
        int 21h
code ends
end start  

上面的源程序中：

• db 'unIX' 相当于 db 75H,6EH,49H,58H， u、 n、 I、 X 的 ASCII 码分别为75H、6EH、49H、58H；
• db 'foRK' 相当于 db 66H,6FH,52H,4BH， f、 o、 R、 K 的ASCII码分别为66H、6FH、52H、4BH；
• mov al,'a' 相当于 mov al,61H，a 的 ASCII 码为61H；
• mov al,'b' 相当于 mov al,62H，b 的 ASCII 码为62H；  

大小写转换的问题

首先分析一下，我们知道同一个字母的大写字符和小写字符对应的 ASCII 码是不同的，比如 “A” 的 ASCII 码是41H，“a” 的 ASCII 码是61H。

要改变一个字母的大小写，实际上就是要改变它所对应的 ASCII 码。

我们可以将所有的字母的大写字符和小写字符所对应的 ASCII 码列出来，进行对比，从中找到规律。

大写        二进制           小写        二进制
 A         01000001          a         01100001
 B         01000010          b         01100010
 C         01000011          c         01100011
 D         01000100          d         01100100

通过对比，我们可以看出来，小写字母的 ASCII 码值比大写字母的 ASCII 码值大20H 。

这样，我们可以想到，如果将 “a” 的 ASCII 码值减去20H，就可以得到 “A”；如果将 “A” 的 ASCII 码值加上20H就可以得到 “a”。

由于此前并没有学习判断指令，因此只能换一种方式，观察，就 ASCII 码的二进制形式来看，除第5位（位数从0开始计算）外，大写字母和小写字母的其他各位都一样。

大写字母 ASCII 码的第5位（位数从0开始计算）为0，小写字母的第5位为1；因此只要把握这个规律就可以进行大小写转换了，这里使用 and 或者 or 指令来实现操作；  

[bx+idata]

在前面，我们可以用 [bx] 的方式来指明一个内存单元， 我们还可以用一种更为灵活的方式来指明内存单元：

[bx+idata] 表示一个内存单元，它的偏移地址为 (bx)+idata（bx 中的数值加上 idata）。

我们看一下指令 mov ax,[bx+200] 的含义：

• 将一个内存单元的内容送入 ax，这个内存单元的长度为2字节（字单元），存放一个字，偏移地址为 bx 中的数值加上200，段地址在 ds 中。
• (ax) = ((ds)*16+(bx)+200)；

指令 mov ax,[bx+200] 也可以写成如下格式（常用）：

• mov ax,[200+bx]；
• mov ax,200[bx]；
• mov ax,[bx].200；

问题

用 Debug 查看内存，结果如下： 2000:1000 BE 00 06 00 00 00 … 写出下面的程序执行后，ax、bx、cx 中的内容。

 mov ax,2000H
 mov ds,ax
 mov bx,1000H
 mov ax,[bx]
 mov cx,[bx+1]
 add cx,[bx+2]

• mov ax,[bx] 是访问的字单元的段地址在 ds 中，即 (ds)=2000H；偏移地址在 bx 中，(bx)=1000H；指令执行后 (ax)=00BEH；
• mov cx,[bx+1] 访问的字单元的段地址在 ds 中，(ds)=2000H；偏移地址 (bx)+1=1001H；指令执行后 (cx)=0600H；
• add cx,[bx+2] 访问的字单元的段地址在 ds 中，(ds)=2000H；偏移地址 (bx)+2=1002H；指令执行后 (cx)=0606H；

有了 [bx+idata] 这种表示内存单元的方式，我们就可以用更高级的结构来看待所要处理的数据。

用 [bx+idata] 的方式进行数组的处理

在 codesg 中填写代码，将 datasg 中定义的第一个字符串，转化为大写，第二个字符串转化为小写。

assume cs:codesg,ds:datasg
datasg segment
db 'BaSiC'
db 'MinIX'
datasg ends

codesg segment
 start: …
codesg ends
end start

按照原来的方法，用 [bx] 的方式定位字符串中的字符。

       mov ax,datasg
       mov ds,ax	
       mov bx,0	
       mov cx,5			
    s: mov al,[bx]		
       and al,11011111b		
       mov [bx],al	
       inc bx			
       loop s
       mov bx,5
       mov cx,5		
   s0: mov al,[bx]
       or al,00100000b		
       mov [bx],al
       inc bx
       loop s0

现在，我们有了 [bx+idata] 的方式，就可以用更简化的方法来完成上面的程序。

我们观察 datasg 段中的两个字符串，一个的起始地址为0，另一个的起始地址为5。

我们可以将这两个字符串看作两个数组，一个从0地址开始存放，另一个从5开始存放。

那么我们可以用 [0+bx] 和 [5+bx] 的方式在同一个循环中定位这两个字符串中的字符。

在这里，0和5给定了两个字符串的起始偏移地址，bx 中给出了从起始偏移地址开始的相对地址。

这两个字符串在内存中的起始地址是不一样的，但是，它们中的每一个字符，从起始地址开始的相对地址的变化是相同的。

改进后的程序：

     mov ax,datasg
	mov ds,ax
	mov bx,0

	mov cx,5
s:	mov al,[bx]			;定位第一个字符串的字符
	and al,11011111b
	mov [bx],al
	mov al,[5+bx]		;定位第二个字符串的字符
	or al,00100000b
	mov [5+bx],al
	inc bx
	loop s

SI 和 DI

SI 和 DI 是 8086CPU 中和 bx 功能相近的寄存器，但是 SI 和 DI 不能够分成两个8 位寄存器来使用。

下面的三组指令实现了相同的功能：

（1）

mov bx,0
mov ax,[bx]

（2）

mov si,0
mov ax,[si]

（3）

mov di,0
mov ax,[di]

用寄存器 SI 和 DI 实现将字符串 ‘welcome to masm!’ 复制到它后面的数据区中；

assume cs:codesg,ds:datasg
datasg segment 
  db 'welcome to masm!'
  db '................'
datasg ends

分析：

我们编写的程序大都是进行数据的处理，而数据在内存中存放，所以我们在处理数据之前首先要搞清楚数据存储在什么地方，也就是说数据的内存地址。

因为 “welcome to masm!” 从偏移地址0开始存放，长度为 16 个字节，所以，它后面的数据区的偏移地址为 16 ，就是字符串所要存放的空间。

用 ds:si 指向要复制的源始字符串，用 ds:di 指向复制的目的空间，然后用一个循环来完成复制。

codesg segment
start: mov ax,datasg
         mov ds,ax
         mov si,0
         mov di,16
         mov cx,8
    s:  mov ax,[si]
         mov [di],ax
         add si,2
         add di,2
         loop s

         mov ax,4c00h
         int 21h
codesg ends
end start

注意：在程序中，用16位寄存器进行内存单元之间的数据传送，一次复制 2 个字节，一共循环8次。

当然，也可以使用 [bx(si/di)+idata] 来使得程序更加简洁：

codesg segment
start: mov ax,datasg
         mov ds,ax
         mov si,0
         mov cx,8
    s:  mov ax,0[si]
         mov 16[si],ax
         add si,2
         loop s
         mov ax,4c00h
         int 21h
codesg ends
end start

[bx+si] 和 [bx+di]

[bx+si] 表示一个内存单元，它的偏移地址为(bx)+(si)（即 bx 中的数值加上 si 中的数值）；

指令 mov ax,[bx+si] 的数学化的描述为：(ax)=( (ds)*16+(bx)+(si) )；

该指令也可以写成如下格式（常用）：mov ax,[bx][si] ；

用 Debug 查看内存，结果如下：

2000:1000 BE 00 06 00 00 00 ……

写出下面的程序执行后，ax、bx、cx中的内容：

mov ax,2000H
mov ds,ax
mov bx,1000H
mov si,0
mov ax,[bx+si]
inc si
mov cx,[bx+si]
inc si
mov di,si
add cx,[bx+di]

解析：

mov ax,[bx+si] ：

访问的字单元的段地址在 ds 中，(ds)=2000H； 偏移地址= (bx)+(si)=1000H； 指令执行后 (ax)=00BEH；

mov cx,[bx+si]： 访问的字单元的段地址在 ds 中，(ds)=2000H； 偏移地址= (bx)+(si)=1001H； 指令执行后 (cx)=0600H；

add cx,[bx+di]： 访问的字单元的段地址在 ds 中，(ds)=2000H； 偏移地址= (bx)+(di)=1002H； 指令执行后 (cx)=0606H；  

[bx+si+idata] 和 [bx+di+idata]

[bx+si+idata] 和 [bx+di+idata] 的含义相似，以 [bx+si+idata] 为例：

[bx+si+idata] 表示一个内存单元，它的偏移地址为 (bx)+(si)+idata（即 bx 中的数值加上 si 中的数值再加上 idata）；

指令 mov ax,[bx+si+idata] 的含义：

将一个内存单元的内容送入 ax，这个内存单元的长度为2字节（字单元），存放一个字，偏移地址为 bx 中的数值加上 si 中的数值再加上idata，段地址在 ds 中。

数学化的描述为：(ax)=( (ds)*16+(bx)+(si)+idata )

该指令也可以写成如下格式（常用）：

mov ax,[bx+200+si]  
mov ax,[200+bx+si]  
mov ax,200[bx][si]  
mov ax,[bx].200[si]  
mov ax,[bx][si].200

用 Debug 查看内存，结果如下：

2000:1000 BE 00 06 00 6A 22 ……

写出下面的程序执行后，ax、bx、cx中的内容：

mov ax,2000H
 mov ds,ax
 mov bx,1000H
 mov si,0
 mov ax,[bx+2+si]
 inc si
 mov cx,[bx+2+si]
 inc si
 mov di,si
 mov ax,[bx+2+di]

解析：

mov ax,[bx+2+si] 访问的字单元的段地址在 ds 中，(ds)=2000H； 偏移地址= (bx)+(si)+2=1002H； 指令执行后 (ax)=0006H；

mov ax,[bx+2+si] 访问的字单元的段地址在 ds 中，(ds)=2000H； 偏移地址= (bx)+(si)+2=1003H； 指令执行后 (cx)=006AH；

mov ax,[bx+2+si] 访问的字单元的段地址在ds中，(ds)=2000H； 偏移地址= (bx)+(si)+2=1004H； 指令执行后 (cx)=226AH；  

不同的寻址方式的灵活应用

如果我们比较一下前面用到的几种定位内存地址的方法（可称为寻址方式），就可以发现有以下几种方式： （1）[iata] 用一个常量来表示地址，可用于直接定位一个内存单元； （2）[bx] 用一个变量来表示内存地址，可用于间接定位一个内存单元； （3）[bx+idata] 用一个变量和常量表示地址，可在一个起始地址的基础上用变量间接定位一个内存单元； （4）[bx+si] 用两个变量表示地址； （5）[bx+si+idata] 用两个变量和一个常量表示地址；

总结：从 [idata] 一直到 [bx+si+idata]，我们可以用更加灵活的方式来定位一个内存单元的地址。这使我们可以从更加结构化的角度来看待所要处理的数据。