问为什么当数字以0结尾时，我的正则表达式失败？

EN

这是对独角兽成瘾者和ZyX的回答的补充:你想匹配什么？

如果你正在尝试匹配'_‘左右的序列，独角兽成瘾者是正确的，并且你的正则表达式需要是^(\d+)_(\d+)$。此外，您还可以完全摆脱第一个限定符和‘IsIntrger()’函数-您已经知道它是一个整数-它匹配(\d+)

if ($string =~ /^(\d+)_(\d+)$/) {
    print "success ('$1','$2')";
} else {
    print "fail\n";
}

如果您试图匹配每一项中的最后一位数字，并且想知道为什么失败，那么这是第一次在IsInteger() ( if($intger && )中进行检查。无论如何，它都是多余的(你知道它是一个整数)，并且在0上失败，因为，正如ZyX所指出的-它的计算结果为false。

不过，同样的事情也适用：

if ($string =~ /^(\d)+_(\d)+$/) {
    print "success ('$1','$2')";
} else {
    print "fail\n";
}

在给定输入12309123098_102938120938120938的情况下，这将输出success ('8','8')

因为在第二个字符串的末尾有0，所以(\d)+只在$N变量中放入最后一个匹配项，string "0"等同于false。

如果不确定，请检查您的正则表达式实际捕获的内容。

use strict;
use warnings;

my @data = (
    '1321312_103810312032123',
    '123123123_10983094854905490',
);

for my $s (@data){
    print "\$1=$1 \$2=$2\n" if $s =~ /^(\d)+_(\d)+$/;
    # Output:
    # $1=2 $2=3
    # $1=3 $2=0
}

您可能打算采用这两种方法中的第二种方法。

(\d)+  # Repeat a regex group 1+ times,
       # capturing only the last instance.

(\d+)  # Capture 1+ digits.

此外，无论是在主循环中还是在IsInteger中(考虑到主循环中的初始正则表达式，这似乎都是不必要的)，您要测试的是真值，而不是更具体的东西，比如defined或length。例如，零是一个有效的整数，但却是假的。