Excel最强函数，16年稳坐C位，12种用法全在这里了！

今晚直播，制作动态看板，想学的记得预约下

有粉丝问道：那个函数你觉得是最强大的？

我不假思索回答道：SUMPRODUCT！

这个函数真的很强大，求和、计数、数据查询它都能轻松搞定，甚至一些疑难杂症，也必须要用到它，它的作用比Vlookup大多了，是职场的必备函数！

一、参数与作用

SUMPRODUCT：返回对应的数组乘积之和

语法：=SUMPRODUCT (array1， [array2]， [array3]， ...)

第一参数：第1个数据区域第二参数：第2个数据区域第三参数：第3个数据区域以此类推，可以设置255个数据区域

使用这个函数我们需要注意一点就是：每一个参数中数据的个数与方向必须相等，否则的话函数就会返回#VALUE!这个错误值。随后我们来看下它的使用方法

二、常规用法

如下图，我们想要根据【单价】与【销量】来计算下总的销售金额

公式：=SUMPRODUCT(B2:B6,C2:C6)

第一参数：B2:B6，单价所在的列

第二参数：C2:C6，销量所在的列

函数会将对应的数据相乘，相乘后会得到一列结果，最后再对这一列数据求和，这个就是SUMPRODUCT函数的作用，返回对应数据的乘积之和，是先相乘，然后再求和

三、逻辑值的冷知识

在Excel中我们可以将逻辑值TRUE看做是1，逻辑值FALSE看做是0，这句话翻译过来就是

条件正确=1

条件错误=0

这点是SUMPRODUCT条件计数与条件求和的基础，只需要记得就可以了，这点总是有很多人问为什么，我只能说：王八的屁股——龟腚（规定），就好比1+1=2一样

四、单条件计数

现在我们想要计算下【行政部】的人数

公式：=SUMPRODUCT((B2:B18=G3)*1)

在这里我们仅仅使用了1个参数，B2:B18=G3是条件，如果部门等于【行政部】就会返回TRUE这个逻辑值，最后还需要将这个乘以1，将逻辑值转换为数字，这样的话SUMPRODUCT才会对齐求和

五、多条件计数

现在我们想要计算下【成型车间】且【级别为2级】的员工人数

公式：=SUMPRODUCT((B2:B20=I2)*(C2:C20=2))

在这里我们也是仅仅使用SUMPRODUCT函数的1个参数，

B2:B20=I2表示【部门等于成型车间】，C2:C20=2表示【员工级别等于2级】

最后让这2个条相乘，就能将逻辑值转换为数值，SUMPRODUCT就能求和计算了

六、单条件求和

单条件求和与单条件计数的原理几乎是一样的，我们只需要将后面的乘1，换成想要求和的列即可，比如现在，我们想要求一下【行政部的薪资总额】

公式：=SUMPRODUCT((B2:B18=H3)*D2:D18)

七、多条件求和

多条件求和与多条件计数是一样的，就是在后面再多乘一个求和列即可

比如现在，我们想要计算【成型车间等级为2级薪资总额】

公式：=SUMPRODUCT((B2:B20=I2)*(C2:C20=2)*D2:D20)

八、排序

公式：=SUMPRODUCT(($C$2:$C$8>C2)*1)+1

这个公式的本质就是一个单条件计数，($C$2:$C$8>C2)*1会计算出比自己大的数值的个数，因为不包含本身，所以结果还需要加1

九、转换表格的维度

公式：=SUMPRODUCT(($A$3:$A$23=$F4)*($B$3:$B$23=G$3)*$C$3:$C$23)

如下图，我们将左侧的1维表格，转换为了右侧的2维表格，这个公式的本质其实就是一个多条件求和，我们通过更改单元格的引用方式，巧妙的将其转换为了2维表格

十、双向求和

所谓双向求和，就是我们需要根据横向与竖向两个方向进行判断求和，现阶段使用SUMPRODUCT是最简单的方法。

如下图，我们想要计算项目【D】的【人工费】

公式：=SUMPRODUCT((A2:A13=H6)*(B1:F1=I6)*B2:F13)

A2:A13=H6在竖向进行判断项目是否等于【D】

B1:F1=I6在横向判断费用类别是否等于【人工费】

B2:F13就是求和的数据数据区域

这两个条件也正好等于B2:F13行列方向的数据个数

十一、隔列求和

如下图，我们想要计算橙色区域的数据之和，就是每隔一列求和

公式：=SUMPRODUCT((MOD(COLUMN(A1:F10),2)=0)*A1:F10)

这个公式的本质是一个SUMPRODUCT单条件求和，MOD(COLUMN(A1:F10),2)=0的作用是判断数字所在的列号是否为偶数列，如果是就求和，如果不是则不求和

十二、隔行求和

还是计算橙色区域的数值之和，现在是每隔一行求和

公式：=SUMPRODUCT((MOD(ROW(A1:F10),2)=0)*A1:F10)

在这里将COLUMN换成了ROW，来获取数据对应的行号，因为计算的还是偶数行。如果想要计算奇数行只需要将等于0，改为等于1即可