问批处理脚本删除文件名或目录中的最后一个字

EN

这应该适用于ren *" "* *" "。但是要小心，因为这会改变目录中的所有内容。如果您知道文件或文件夹的第一个单词，那么您可以使用这个ren 1stword" "* *" "。

@ECHO OFF
SETLOCAL enabledelayedexpansion
FOR %%t IN (*) DO (
  CALL :process "%%~nt"
  IF DEFINED success ECHO REN "%%t" "!success!%%~xt"
  )
GOTO :eof

:process
SET "success=%~1"
:procloop
SET "lastchar=%success:~-1%"
SET "success=%success:~0,-1%"
IF NOT DEFINED success GOTO :EOF 
IF NOT "%lastchar%"==" " GOTO procloop
:: Remove any other trailing spaces
:rtsloop
SET "lastchar=%success:~-1%"
SET "success=%success:~0,-1%"
IF "%lastchar%"==" " GOTO rtsloop
SET "success=%success%%lastchar%"
GOTO :eof

对于大多数“正常”的名字来说，这应该是有用的。对于包含极少数字符(如!和^ )的名称，它可能会失败--但是这样的文件/目录名是愚蠢的。

将FOR更改为FOR /d以处理目录，而不是文件。

本质上，NAME部分以引号形式传递给:process例程以保留其间距，该例程首先删除最终字符，直到找到一个空格，然后继续删除任何进一步的空格。

如果名称没有空格，success将为空，因此未定义，否则它将有新的名称。

验证后，将ECHO REN更改为简单的REN以进行重命名，此例程只报告它打算做的事情。

增编：

我们有个术语上的难题。

对于FILES，FILENAME.TXT如果经常被称为文件的“名称”，但是FILENAME是“名称”，而.TXT是扩展名。

当发生此过程时，期望的结果是FILENAME WITH SPACES.EXT变为FILENAME WITH.EXT，以保留文件的扩展名或类型。

对于目录名，仍然支持“扩展”的思想，因此Folder 18.9.0.17被视为具有.17扩展的Folder 18.9.0 (扩展是在最终.之后发生的任何事情)。

解决方法非常简单--不要在重命名中添加扩展名。

  IF DEFINED success ECHO REN "%%t" "!success!"

(但请注意，Folder 18.9.0.17、Folder 18.9.0.18、Folder 18.9.0.19将ALL的目标重命名为Folder --只有第一个可能成功.)