OpenTK：使用几何着色器破解点的大小限制

#version 460 core

layout(location = 0) in vec2 aPosition;  
layout(location = 1) in vec3 aColor;
layout(location = 2) in float aSize;

out VS_OUT {
    vec3 color;
    float size;
} vs_out;

void main(void)
{
    gl_Position = vec4(aPosition, 0.0, 1.0);
	vs_out.color = aColor;
    vs_out.size = aSize;
}

#version 460 core

layout (points) in;
layout (triangle_strip, max_vertices = 4) out;

in VS_OUT {
    vec3 color;
    float size;
} gs_in[];

out vec3 fColor;
out vec2 fTexCoord;

uniform mat4 mvp;

void main()
{
    vec4 center = gl_in[0].gl_Position;
    fColor = gs_in[0].color;
    float size = gs_in[0].size;
    
    gl_Position = mvp * (center + vec4(-size, size, 0.0, 0.0));
    fTexCoord = vec2(0.0, 1.0);
    EmitVertex();
    
    gl_Position = mvp * (center + vec4(size, size, 0.0, 0.0));
    fTexCoord = vec2(1.0, 1.0);
    EmitVertex();
    
    gl_Position = mvp * (center + vec4(-size, -size, 0.0, 0.0));
    fTexCoord = vec2(0.0, 0.0);
    EmitVertex();
    
    gl_Position = mvp * (center + vec4(size, -size, 0.0, 0.0));
    fTexCoord = vec2(1.0, 0.0);
    EmitVertex();
    
    EndPrimitive();
}

#version 460 core

in vec3 fColor;
in vec2 fTexCoord;

out vec4 outputColor;
const float smoothness = 0.02;

void main()
{
    vec2 center = vec2(0.5, 0.5);
    float distance = distance(fTexCoord, center);
    if (distance > 0.5) discard;

    float alpha = 1.0 - smoothstep(0.5 - smoothness, 0.5, distance);
    outputColor = vec4(fColor, alpha);
}

// OpenGL版本
string glVersion = GL.GetString(StringName.Version);

// GLSL版本
string glslVersion = GL.GetString(StringName.ShadingLanguageVersion);

// 渲染器
string renderer = GL.GetString(StringName.Renderer);

// 供应商
string vendor = GL.GetString(StringName.Vendor);

// 获取点大小的最小和最大范围（平滑）
float[] pointSizeRangeSmooth = new float[2];
GL.GetFloat(GetPName.SmoothPointSizeRange, pointSizeRangeSmooth);
float minPointSizeSmooth = pointSizeRangeSmooth[0];
float maxPointSizeSmooth = pointSizeRangeSmooth[1];

// 获取点大小颗粒度/增量 (Granularity)
// 这表示在平滑模式下，点大小可以增加的最小步进值
float pointSizeGranularity = GL.GetFloat(GetPName.SmoothPointSizeGranularity);