四舍五入(PUT & ROUND) 与数据顺序影响Proc means 结果

归海刀刀

发布于 2025-06-20 11:53:10

9900

代码可运行

文章被收录于专栏：归海刀刀归海刀刀

运行总次数：0

代码可运行

Mean

—Proc means。

参考资料：

SAS 数值存储方式和精度问题

https://www.cnblogs.com/snoopy1866/p/16021137.html

put和round保留小数

https://bbs.pinggu.org/thread-6433632-1-1.html

SAS 四舍五入 - PUT 与 ROUND

https://www.cnblogs.com/pluuus230713/p/17729557.html

通常生成summary table的时候会对统计量进行四舍五入以达到相应的保留位数要求，可是同一批数据，对于传入proc mean数据集的顺序不同会产生不同的结果，put出来的结果不一样，以下程序复现了这一过程

data GHDD;
infile datalines dsd missover;
input aval;
datalines;

85.3
100.7
84.7
99.3
79.3
91.3

;
run;

proc sort data=GHDD out=by1;
 by aval;
run;
proc sort data=GHDD out=by2;
 by descending aval;
run;

proc means data=by1;
 var aval;
 output out=by1_sum;
run;

proc means data=by2;
 var aval;
 output out=by2_sum;
run;

data by1_sum;
 length putc roundputc hex $200.;
 set by1_sum;
 putc=strip(put(aval,14.2));
 roundputc=strip(put(round(aval,0.000000001),14.2));
 hex=put(aval,hex16.);
run;

data by2_sum;
 length putc roundputc hex $200.;
 set by2_sum;
 putc=strip(put(aval,14.2));
 roundputc=strip(put(round(aval,0.000000001),14.2));
 hex=put(aval,hex16.);
run;

proc compare base=by1_sum comp=by2_sum listall CRITERION=0.000000001 MAXPRINT=(,);

run;