【汇编语言】int指令（一）—— 中断与栈的联动机制：透视int与iret的核心原理

前言

📌 汇编语言是很多相关课程（如数据结构、操作系统、微机原理）的重要基础。但仅仅从课程的角度出发就太片面了，其实学习汇编语言可以深入理解计算机底层工作原理，提升代码效率，尤其在嵌入式系统和性能优化方面有重要作用。此外，它在逆向工程和安全领域不可或缺，帮助分析软件运行机制并增强漏洞修复能力。 本专栏的汇编语言学习章节主要是依据王爽老师的《汇编语言》来写的，和书中一样为了使学习的过程容易展开，我们采用以8086CPU为中央处理器的PC机来进行学习。

1. int 指令

中断信息可以来自CPU的内部和外部，当CPU的内部有需要处理的事情发生的时候，将产生需要马上处理的中断信息，引发中断过程。在前面一个章节中，我们讲解了中断过程和两种内中断的处理。

这一章中，我们讲解另一种重要的内中断。

是什么呢？

那就是DOS时代大名鼎鼎的int中断。

1.1 格式以及功能

int指令的格式为： int n，n为中断类型码。它的功能是引发中断过程。

CPU 执行int n指令，相当于引发一个 n号中断的中断过程，执行过程如下：

• （1）取中断类型码n；
• （2）标志寄存器入栈，IF = 0，TF = 0；
• （3）CS、IP入栈；
• （4）(IP) = (n*4)，(CS) = (n*4+2)。

从此处转去执行n号中断的中断处理程序。

1.2 举例说明

可以在程序中使用int指令调用任何一个中断的中断处理程序。

1.2.1 源程序

例如，下面的程序：

assume cs:code

code segment
  
start: 
		mov ax,0b800h
        mov es,ax
        mov byte ptr es:[12*160+40*2],'!'
		
        int 0
code ends
 
end start

1.2.2 分析源程序

这个程序在 Windows 2000 中的DOS方式下执行时，将在屏幕中间显示一个“!”，然后显示“Divide overflow”后返回到系统中。

“!”是我们编程显示的，而“Divide overflow”是哪里来的呢？

我们的程序中又没有做除法，不可能产生除法溢出。

程序是没有做除法，但是在结尾使用了int 0指令。CPU执行int 0指令时，将引发中断过程，执行0号中断处理程序，而系统设置的0号中断处理程序的功能是显示“Divide overflow”，然后返回到系统。

1.3 总结

可见，int指令的最终功能和cal指令相似，都是调用一段程序。

一般情况下，系统将一些具有一定功能的子程序，以中断处理程序的方式提供给应用程序调用。

我们在编程的时候，可以用int指令调用这些子程序。当然，也可以自己编写一些中断处理程序供别人使用。

以后，我们可以将中断处理程序简称为中断例程。

2. 编写供应用程序调用的中断例程

前面，我们已经编写过中断0的中断例程了，现在我们讨论可以供应用程序调用的中断例程的编写方法。

下面通过两个实例来讨论。

2.1 实例一

2.1.1 问题

• 问题：编写、安装中断 7ch 的中断例程
• 功能：求一个word 型数据的平方。
• 参数：(ax)=要计算的数据。
• 返回值：dx、ax中存放结果的高16位和低16位。

应用举例：求 2*3456^2，示例代码如下：

assume cs:code
code segment
start: 
	 mov ax,3456	;(ax)=3456
     int 7ch		;调用中断7ch的中断例程，计算ax中的数据的平方
     add ax,ax	
	 adc dx,dx  	;存放结果，将结果乘以2
	 mov ax,4c00h
     int 21h
code ends
end start 

2.1.2 分析与解答

分析一下，我们要做三部分工作：

• （1）编程实现求平方功能的程序；
• （2）安装程序，我们将其安装在0:200处；
• （3）设置中断向量表，将程序的入口地址保存在7ch表项中，使其成为中断7ch的中断例程。

安装程序如下：

assume cs:code

code segment
start:
		mov ax,cs
		mov ds,ax
		mov si,offset sqr					;设置ds:si指向源地址
		mov ax,0
		mov es,ax
		mov di,200h							;设置es:di指向目的地址
		mov cx,offset sqrend - offset sqr	;设置cx为传输长度
		cld									;设置传输方向为正
		rep movsb

		mov ax,0
		mov es,ax
		mov word ptr es:[7ch*4],200h
		mov word ptr es:[7ch*4+2],0

		mov ax,4c00h
		int 21h

  sqr:  
		mul ax
		iret
sqrend:	nop

code ends
end start

❗注意，在中断例程 sqr的最后，要使用iret指令。

用汇编语法描述，iret指令的功能为：

pop IP
pop CS
popf

CPU执行int 7ch指令进入中断例程之前，标志寄存器、当前的CS和IP被压入栈中，在执行完中断例程后，应该用iret指令恢复int 7ch 执行前的标志寄存器和CS、IP的值，从而接着执行应用程序。

✍int指令和 iret指令的配合使用与call指令和ret指令的配合使用具有相似的思路。

2.2 实例二

2.2.1 问题

• 问题：编写、安装中断7ch的中断例程。
• 功能：将一个全是字母，以0结尾的字符串，转化为大写。
• 参数：ds:si指向字符串的首地址。

应用举例： 将data段中的字符转化为大写，示例代码如下：

assume cs:code
data segment
    db 'conversation',0
data ends
code segment
    start:   mov ax,data
             mov ds,ax
             mov si,0
             int 7ch
  	         mov ax,4c00h
	         int 21h
code ends
end start

2.2.2 分析与解答

安装程序如下：

assume cs:code
code segment

start:
		mov ax,cs
		mov ds,ax
		mov si,offset capital
		mov ax,0
		mov es,ax
		mov di,200h
		mov cx,offset capitalend - offset capital
		cld
		rep movsb

		mov ax,0
		mov es,ax
		mov word ptr es:[7ch*4],200h
		mov word ptr es:[7ch*4+2],0

		mov ax,4c00h
		int 21h

capital:
		push cx
		push si
		
change: 
		mov cl,[si]
		mov ch,0
		jcxz ok
		and byte ptr [si],11011111b
		inc si
		jmp short change
ok:	
		pop si
		pop cx
		iret
		
capitalend:nop

code ends

end start

最后，在中断例程capital中用到了寄存器 si和cx，编写中断例程和编写子程序的时候具有同样的问题，就是要避免寄存器的冲突。

应该注意例程中用到的寄存器的值的保存和恢复。

3. 对int、iret和栈的深入理解

3.1 问题引入

问题：用7ch中断例程完成 loop指令的功能。

loop s 的执行需要两个信息，循环次数和到s的位移，所以，7ch中断例程要完成loop指令的功能，也需要这两个信息作为参数。

我们用cx存放循环次数，用bx存放位移。

应用举例：在屏幕中间显示80个‘！’，示例代码如下：

assume cs:code

code segment
start: 
      mov ax,0b800h
	  mov es,ax
	  mov di,160*12
	  
	  mov bx,offset s - offset se       ;设置从标号se到标号s的转移位移
	  mov cx,80
   s: mov byte ptr es:[di],'!'
	  add di,2
	  int 7ch                           ;如果(cx)≠0，转移到标号s处
 se:  nop
 
	  mov ax,4c00h
	  int 21h
code ends

end start

在上面的程序中，用int 7ch调用7ch中断例程进行转移，用 bx 传递转移的位移。

3.2 分析

3.2.1 中断例程应该具备的功能

分析：为了模拟loop指令，7ch中断例程应具备下面的功能：

• （1）dec cx
• （2）如果(cx)≠0，转到标号s 处执行，否则向下执行。

3.2.2 如何实现目标地址的转移？

• （1）转到标号s显然应设(CS)=标号s的段地址，(IP)=标号s的偏移地址。
• （2）那么，中断例程如何得到标号s的段地址和偏移地址呢？

int 7ch 引发中断过程后，进入 7ch 中断例程，在中断过程中，当前的标志寄存器、CS和IP都要压栈，此时压入的CS和IP中的内容，分别是调用程序的段地址（可以认为是标号s的段地址）和 int 7ch后一条指令的偏移地址（即标号se的偏移地址）。

可见，在中断例程中，可以从栈里取得标号s的段地址和标号se的偏移地址，而用标号se的偏移地址加上bx中存放的转移位移就可以得到标号s的偏移地址。

• （3）现在知道，可以从栈中直接和间接地得到标号s的段地址和偏移地址，那么如何用它们设置CS:IP呢？

可以利用iret指令，我们将栈中的se的偏移地址加上bx中的转移位移，则栈中的 se的偏移地址就变为了s的偏移地址。 我们再使用iret指令，用栈中的内容设置CS、IP，从而实现转移到标号s处。

3.3 得到中断例程程序

7ch中断例程如下：

lp:    push bp
       mov bp,sp
	   dec cx			;cx自减一
	   jcxz lpret
	   add [bp+2],bx

lpret: pop bp
	   iret

因为要访问栈，使用了bp，在程序开始处将bp入保存，结束时出恢复。

当要修改栈中se的偏移地址的时候，栈中的情况为：

1. 栈顶处是bp原来的数值，
2. 下面是se的偏移地址，
3. 再下面是s的段地址，
4. 再下面是标志寄存器的值。

而此时，bp中为顶的偏移地址，所以((ss)*16+(bp)+2)处为se的偏移地址，将它加上bx中的转移位移就变为s的偏移地址。

最后用iret出栈返回，CS:IP即从标号s处开始执行指令。

如果(cx)=0，则不需要修改栈中 se 的偏移地址，直接返回即可。CPU 从标号 se 处向下执行指令。

结语

今天的分享到这里就结束啦！如果觉得文章还不错的话，可以三连支持一下。

也可以点点关注，避免以后找不到我哦！

Crossoads主页还有很多有趣的文章，欢迎小伙伴们前去点评，您的支持就是作者前进的动力！